I am trying to take an array and convert it to a string. I know that Split will let me easily go the other way. I searched for the converse of Split but have not been able to locate it. I can think of two brute force methods of doing this. I found an answer to something similar in the forum and adapted it - but it is so much code for such a simple procedure:

import std;
void main()
{
    auto a = [1,0,1,1,1,0,1,0,1,1,1,1,0];

    string b = to!string(a.map!(to!string)
     .chunks(a.length)
     .map!join);

    string f = b[2..b.length-2];  //needed to strip the first two and las two characters
    writeln(f);

}

I want to come out of this with a string that looks like this: 1011101011110

Thanks in advance.

On Thursday, 8 April 2021 at 03:57:23 UTC, Brad wrote:

You need two functions here:

1. joiner [1], which lazily joins the elements of a range.
2. array [2], which eagerly evaluates a range and returns an array of its elements.

The final code looks like this:

dchar[] b = a.map!(to!string).joiner.array;

You may have noticed that the type of b here is dchar[], not string. This is due to a feature of D's standard library known as "auto decoding" [3]. To prevent the strings you get from to!string from being auto-decoded into ranges of dchar, you can use the function std.utf.byCodeUnit [4], like this:

string b = a.map!(to!string).map!(byCodeUnit).joiner.array;

[1] https://phobos.dpldocs.info/std.algorithm.iteration.joiner.1.html
[2] https://phobos.dpldocs.info/std.array.array.1.html
[3] https://jackstouffer.com/blog/d_auto_decoding_and_you.html
[4] https://phobos.dpldocs.info/std.utf.byCodeUnit.html

On Thursday, 8 April 2021 at 03:57:23 UTC, Brad wrote:

import std;
void main()
{
    auto a = [1,0,1,1,1,0,1,0,1,1,1,1,0];

    string b = to!string(a.map!(to!string)
     .chunks(a.length)
     .map!join);

    string f = b[2..b.length-2];  //needed to strip the first two and las two characters
    writeln(f);

}

string to01String(int[] x) @safe
{
    auto conv = x.to!(ubyte[]); // allocates new array, so later cast to string is OK
    conv[] += '0'; // assume all numbers are 0-9, then this gives the correct result
    return (() @trusted => cast(string)conv)();
}

On Thursday, 8 April 2021 at 12:19:29 UTC, WebFreak001 wrote:

string to01String(int[] x) @safe
{
    auto conv = x.to!(ubyte[]); // allocates new array, so later cast to string is OK
    conv[] += '0'; // assume all numbers are 0-9, then this gives the correct result
    return (() @trusted => cast(string)conv)();
}

The @trusted lambda can also be replaced with std.exception.assumeUnique.

On Thursday, 8 April 2021 at 18:01:56 UTC, Meta wrote:

string to01String(int[] x) @safe
{
    auto conv = x.to!(ubyte[]); // allocates new array, so later cast to string is OK
    conv[] += '0'; // assume all numbers are 0-9, then this gives the correct result
    return (() @trusted => cast(string)conv)();
}

Never mind me, assumeUnique is @system (or at least it's inferred as @system), and anyway, you can't implicitly convert immutable(ubyte)[] to immutable(char)[].

The ascii code of 0 is 48 so I think you can add everywhere 48 (but I'm not a specialist)