Soket Oluşturma Örneği[İstek]

import std.stdio;
import std.socket;
import std.getopt;
import std.string;

enum port = 8080;

int main(string[] parametreler)
{
   // Sunucu rolünde mi olalım istemci mi
   enum Rol { sunucu, istemci }
   Rol rol;

   try {
       // Rol olamayacak değer geldiğinde hata atar
       getopt(parametreler, "rol", &rol);

   } catch {
       stderr.writefln("Kullanım:\n    %s --rol={sunucu|istemci}",
                       parametreler[0]);
       return 1;
   }

   final switch (rol) {
   case Rol.sunucu:  sunucu(); break;
   case Rol.istemci: istemci(); break;
   }

   return 0;
}

void sunucu()
{
   // Önce bağlantıları karşılayacak olan soketi hazırlıyoruz
   auto dinleyici = new TcpSocket();
   scope (exit) {
       /* Gereken temizlik işlemleri
        *
        * Not: Tabii ki alt düzeyler kavramlar olan soketlerle böyle uğraşmak
        * yerine soketi sarmalayan bir Soket yapısı tanımlayabiliriz ve bu
        * işlemleri o türün sonlandırıcısında yapabiliriz. */

       writefln("Yerel %s kapatılıyor", dinleyici.localAddress());

       // BOTH: "hem okuma hem yazma" anlamında
       dinleyici.shutdown(SocketShutdown.BOTH);
       dinleyici.close();
   }

   // Hangi portu dinleyeceğini belirtiyoruz
   dinleyici.bind(new InternetAddress(port));
   writefln("Port: %s", port);

   // İstemci bekliyoruz
   dinleyici.listen(1);
   writefln("Bekliyorum...");

   // Şimdi o sokette bağlantı kabul ediyoruz
   Socket bağlantı = dinleyici.accept();
   scope (exit) {
       writefln("İstemci bağlantısı %s kapatılıyor", bağlantı.remoteAddress());
       bağlantı.shutdown(SocketShutdown.BOTH);
       bağlantı.close();
   }
   writefln("İstemci bağlandı: %s", bağlantı.remoteAddress());

   // Okunan veriyi bu belleğe alacağız
   ubyte[1000] bellek;
   bool bitti_mi = false;

   while (!bitti_mi) {
       const adet = bağlantı.receive(bellek);

       if (adet == Socket.ERROR) {
           writefln("OKUMA HATASI");

       } else {
           writefln("%s bayt aldım: %s", adet, bellek[0..adet]);
           // Okunan verinin ne anlama geldiği bütünüyle sunucu ve istemci
           // arasındaki protokole bağlıdır.
       }

       bitti_mi = (adet < bellek.length);
   }
}

void istemci()
{
   auto bağlantı = new TcpSocket();
   bağlantı.connect(new InternetAddress("127.0.0.1", port));
   scope (exit) {
       bağlantı.shutdown(SocketShutdown.BOTH);
       bağlantı.close();
   }

   // Bu örnekte mesajı string olarak göndereceğiz. Aslında send() parametre
   // olarak const(void)[] alır.
   string mesaj = format("%s%s%s", "merhaba", 42, "dünya");
   const adet = bağlantı.send(mesaj);
   writefln("%s bayt gönderdim", adet);
}

Ali

--
[ Bu gönderi, http://ddili.org/forum'dan dönüştürülmüştür. ]

Guzel bir konu aslinda ben de soket hakkinda bir konu acmistim sorum bu yondeydi :)

Simdi bilgimin yetmedigi bir noktadan soru soracagim yuzeysel cevap yeterli olur mantik acisindan.

Ornegin bir program var. Bu programa konsoldan bir deger giriyoruz. Bu degerleri isliyoruz ve sadece bu programa ozel bi port ile istemci baslatiyoruz. Bunu nasil saglariz acaba.

ornegin phpmyadmin :) mysql 3306 portunu kullaniyor ve ornegin 3306 portuna erisim saglanmazsa phpmyadmin'e ulasim saglanmiyor. ben de buna benzer bi konu dusunuyorum da acaba yapilabilir mi?

localhost:1907 gibi cagiricam ve degerleri arayuzde gostericem. Sorun html tasarim vs. degil :) konsoldan islemi yaparken, veri eklerken mutlaka bir port'a bagli olmak gerekiyor. bunlar mumkun olan seyler mi? yapmak icin neler gerekiyor acaba? :)

Ben derdimi aslinda aciklayamadim :( Anlayabilen abiler, arkadaslarim aciklayabilir mi derdimi? :)

--
[ Bu gönderi, http://ddili.org/forum'dan dönüştürülmüştür. ]

Forums