Is there a way to find a struct which should be passed by reference but accidentally isn't? Maybe with copy constructors?

On Monday, 2 August 2021 at 23:06:42 UTC, frame wrote:

@disable postblit:

struct NoCopy {
    int n;
    @disable this(this);
}

void modify(NoCopy nc) {
    nc.n++;
}

void main() {
    NoCopy x;
    x.modify; // Error: struct `catchcopy.NoCopy` is not copyable ...
}

std.typecons.Unique:

import std.typecons : Unique;

class Val {
    int n;
}

void incr(Unique!Val v) {
    v.n++;
}

void decr(ref Unique!Val v) {
    v.n--;
}

void show(Unique!Val v) {
    import std.stdio : writeln;

    writeln(v.n);
}

void main() {
    Unique!Val x = new Val;
    // x.incr; // Error: ... is not copyable
    x.decr;
    x.release.show;
}

On Monday, 2 August 2021 at 23:19:48 UTC, jfondren wrote:

Well, I have to change a struct to be passed by reference now and don't want to manually inspect where the compiler complains - which is nearly everwhere. The compiler would also not distinguish between a reference assignment.

This could work, thanks for the hint.

On Tuesday, 3 August 2021 at 10:25:34 UTC, frame wrote:

I was too optimistic. I get the error:

struct `std.typecons.Unique!(myType).Unique` is not copyable because it is annotated with `@disable`

on a line like:

Unique!myType rs = query();

which body is:

ref Unique!myType query(A...)(A args)
{
   return queryImpl(args); // also ref to ref, back to creation of the struct
}

It's not an Unique! problem, I also get the error if I just disable the postblit.
Removing the ref from queryImpl! prints the error at query(), so it really sees the error just at the line above but why?

On Tuesday, 3 August 2021 at 11:31:02 UTC, frame wrote:

struct `std.typecons.Unique!(myType).Unique` is not copyable because it is annotated with `@disable`

Unique!myType rs = query();

ref Unique!myType query(A...)(A args)
{
   return queryImpl(args); // also ref to ref, back to creation of the struct
}

You can't assign a ref to a variable; if you try, a copy is created.

What you can do instead is use a pointer:

Unique!myType* rs = &query();

On Tuesday, 3 August 2021 at 11:55:51 UTC, Paul Backus wrote:

Unique!myType* rs = &query();

Thanks. I feared that. So something like

ref T var = ...

does not exist (yet)?

On Tuesday, 3 August 2021 at 12:23:38 UTC, frame wrote:

Unique!myType* rs = &query();

ref T var = ...

No. ref can only be used as a function/template. or foreach parameter.
eg:

void main()
{
    ref int i;
}



error: variable `onlineapp.main.i` only parameters or `foreach` declarations can be `ref`

On Tuesday, 3 August 2021 at 13:23:04 UTC, Tejas wrote:

Yeah, I know. I was in hope of a DIP or something.
I just would like to hijack the reference chain to do something like:

void fun()
{
  ref T rs;

  scope(failure)
  {
    rs.close();
  }

  rs = query();
  otherFunc(rs);
}

I removed the ref and changed my code to use pointers instead.