If the constructor of a class needs to create an array of structs whose dimensions are inputs, what's the syntax for doing this?

For a non-example, the following program errors in main() because in t.array[][] "index [0] is out of bounds".

import std.stdio;

struct Point
{
 uint x;
 uint y;
 void printInfo()
 {
    printf("(%d $d )",x,y);
 }
}


class testClass
{
  uint dimension;
  Point[][] array;

  this(uint the_dimension)
  {
    dimension = the_dimension;
    auto array = new Point[][](the_dimension,the_dimension);
    for(uint i = 0; i < dimension; i++)
    {
       for(uint j = 0; j < dimension; j++)
       {
          array[i][j].x = i;
          array[i][j].y = j;
       }
    }
  }
}

void main()
{
   auto t = new testClass(5);

   for(uint i = 0; i < t.dimension; i++)
   {
      for(uint j = 0; j < t.dimension; j++)
      {
        printf("(%d %d)",t.array[i][j].x, t.array[i][j].y);
         //t.array[i][j].printInfo();
      }

   }

}

On Tuesday, 23 January 2024 at 18:15:29 UTC, Stephen Tashiro wrote:

struct Point
{
 uint x;
 uint y;
 void printInfo()
 {
    printf("(%d $d )",x,y);
 }
}


class testClass
{
  uint dimension;
  Point[][] array;

  this(uint the_dimension)
  {
    dimension = the_dimension;
    auto array = new Point[][](the_dimension,the_dimension);
    for(uint i = 0; i < dimension; i++)
    {
       for(uint j = 0; j < dimension; j++)
       {
          array[i][j].x = i;
          array[i][j].y = j;
       }
    }
  }
}

void main()
{
   auto t = new testClass(5);

   for(uint i = 0; i < t.dimension; i++)
   {
      for(uint j = 0; j < t.dimension; j++)
      {
        printf("(%d %d)",t.array[i][j].x, t.array[i][j].y);
         //t.array[i][j].printInfo();
      }

   }

}

This works , your mistake was to not actually assign the array to the class' field!

Change this line:

auto array = new Point[][](the_dimension,the_dimension);

To this:

this.array = new Point[][](the_dimension,the_dimension);

On Tuesday, 23 January 2024 at 19:32:31 UTC, Stephen Tashiro wrote:

This is how you create a multidimensional array in D that's allocated on the heap.

The wiki mentions this: https://wiki.dlang.org/Dense_multidimensional_arrays

You could also create a "static array" (on the stack, not heap):

import std.stdio;

void main() {
    // allocate on the heap
    int[][] matrix = new int[][](5, 2);
    writeln(matrix);

    // allocate on the stack (I don't actually know why the dimensions are reversed!
    int[2][5] matrix2;
    writeln(matrix2);
}

This prints [[0, 0], [0, 0], [0, 0], [0, 0], [0, 0]] twice as they're the same matrix.

I normally look at the D website, under the header Language Reference, which links to https://dlang.org/spec/spec.html

If you're looking for just basics, the D Tour is much more friendly though, click on the Learn header: https://tour.dlang.org/

And then try to find what you want either in D's Basics or D's Gems (or the other headers which are specific to other topics)... these pages normally have links to more in-depth material, so it's always a good starting point.

I you're looking for standard library help, then instead of clickin on Language Reference on the D's landing page, click on Library Reference instead. Almost all stdlib is either under std or core.

On Tuesday, 23 January 2024 at 18:15:29 UTC, Stephen Tashiro wrote:

You need to remove auto from
auto array = new Point[][](the_dimension,the_dimension);
because it creates a new variable.