Merhaba,

Variant (https://github.com/D-Programming-Language/phobos/blob/master/std/variant.d) türü ile ilgili kitaptada pek kaynak bulamadım. Sadece "Beklenmeyen mesaj almak" başlıklı konuda "her türden veriyi
sarmalayabilen bir türdür" şeklinde bir açıklama geçiyor.

Benim anladığım kadarıyla diğer dillerde bulunan ve her türlü veriyi taşıyabilen Object türünün bir benzeri, denemek ve tanımak istedim. Aşağıda küçük bir örnek var bir yapıyı (struct) Variant bir değişkene aktardım ancak kendi türünde bir değişkene geri aktaramıyorum?

import std.stdio;
import std.variant;

void main()
{
   Klavye q = Klavye("Q klavye");
   Klavye f = Klavye("F klavye");

   Variant v = q;

   Klavye t = cast(Klavye)v;

   writeln(t.adi);
}

struct Klavye
{
   string adi;
}

'// Hata mesajı'

main.d(13): Error: cannot cast expression v of type VariantN!32LU to Klavye because of
different sizes
shell returned 1

--
[ Bu gönderi, http://ddili.org/forum'dan dönüştürülmüştür. ]

Açıklama ve kodlar için teşekkürler çok faydalı oldu. İlk defa gördüğüm ve yabancı gelen TypeInfo ve typeid hakkında biraz daha bilgi verebilir misin? Biraz araştırdım ancak pek bir bilgi bulamadım. Örneğin nerede ve niçin kullanıyorlar?

Ayrıca konuyu daha derinlemesine incelemek isteyenler için anahtar kelimeler: tagged union, variant, variant record, discriminated union, disjoint union, sum type.

--
[ Bu gönderi, http://ddili.org/forum'dan dönüştürülmüştür. ]

Alıntı (zafer):

Variant, discriminated union denen yapının bir uygulamasıdır. Ben daha önce C++'ta boost::any türüyle kullanmıştım. En basit olarak, bir union'dan ve belirli bir anda o union'ın üyelerinden hangisinin kullanılmakta olduğunu bilen bir enum'dan oluşur. (Bir kaç gün önce öğrendiğim nan-boxing yöntemi enum'a gerek bırakmıyor. Bunun hakkında da yazmak istiyorum ama zaman bulunca... :) )

Variant'ın gerçekleştirmesi kabaca şunun gibidir (burada kolaya kaçarak TypeInfo kullandım; küçük bir enum kullanıldığında daha az yer tutabilir):

import std.format;
import std.exception;

struct HerTür
{
   union
   {
       int i;
       double d;
   }

   TypeInfo tür;

   void yaz(T)(T veri)
   {
       static if (is (T == int)) {
           i = veri;

       } else static if (is (T == double)) {
           d = veri;
       }

       tür = typeid(T);
   }

   T oku(T)()
   {
       if (typeid(T) != tür) {
           throw new Exception(format("%s türündeki veri %s olarak okunamaz"));
       }

       static if (is (T == int)) {
           return i;

       } else static if (is (T == double)) {
           return d;
       }
   }
}

void main()
{
   HerTür ht;

   ht.yaz(42);
   assert(ht.oku!int() == 42);

   // Aynı değişkene başka tür yerleştiriyoruz:
   ht.yaz(1.5);
   assert(ht.oku!double() == 1.5);

   // Yanlış tür olarak okumaya çalıştığımızda hata atılır:
   assertThrown(ht.oku!int);
}

Variant'a bakarken Algebraic'e de bakmak gerek. Yanılmıyorsam daha kullanışlı bir tür...

Alıntı:

>     Klavye t = cast(Klavye)v;
> ```

>

Herhalde güvenli olsun diye 'DÜZELTME:'~~otomatik~~ elle yapılan dönüşümü engellemiş olmalılar. Variant'ın 'peek' işlevine hangi tür istediğimizi söylemek gerekiyor. Gösterge döndürdüğünden de * işleci:

Klavye t = *v.peek!Klavye;

Neyse ki == işlecinde otomatik tür dönüşümü var. Şu işliyor:

assert(v == q);

Ali

-- 
[ Bu gönderi, <http://ddili.org/forum>'dan dönüştürülmüştür. ]

Değeri okumak için daha kolayı varmış:

   Klavye t = v.get!Klavye();

Ek olarak, galiba onlar da enum değil, TypeInfo kullanıyorlar.

Ali

--
[ Bu gönderi, http://ddili.org/forum'dan dönüştürülmüştür. ]

Alıntı (zafer):

Ben de dün kitaba eklenmeleri gerektiğini not almıştım. :)

typeid, değeri TypeInfo türünde olan bir ifade:

http://dlang.org/expression.html#TypeidExpression

TypeInfo, tür ile ilgili ancak çalışma zamanında bilinen bilgi veriyor:

http://dlang.org/phobos/object.html#.TypeInfo

Ben kitapta getHash() üye işlevini kullanmıştım. getHash, "bu türün eşleme tablosu anahtarını üreten işlevi nedir?" sorusunu yanıtlıyor:

http://ddili.org/ders/d/object.html

Bir kaç gün içinde ekleyeceğim.

Ali

--
[ Bu gönderi, http://ddili.org/forum'dan dönüştürülmüştür. ]