Hi,

I try to convert some python code to D. On python I can get the cpu time for the current
process using

dcpu: float = time.process_time()

Is there some equivalent function in Phobos to get the cpu time on linux?

Kind regards
André

On Friday, 7 May 2021 at 08:25:43 UTC, Andre Pany wrote:

dcpu: float = time.process_time()

Take a look at https://code.dlang.org/packages/getr

On Friday, 7 May 2021 at 08:37:47 UTC, Imperatorn wrote:

dcpu: float = time.process_time()

Thanks a lot :)

Kind regards
André

On Friday, 7 May 2021 at 08:25:43 UTC, Andre Pany wrote:

I don't think so, but you can use core.sys.posix.sys.resource: rusage.

If you want to use it on Windows as well, this is a code snippet I wrote for that:

/// Describes how much cpu time a process has been getting
struct CpuUsage {
	/// Time that the process has executed in kernel mode in microseconds
	ulong kernelTimeUs;

	/// Time that the process has executed in user mode in microseconds
	ulong userTimeUs;
}

bool getCpuUsage(out CpuUsage r) {
	version(Windows) {
		void* currentProcess = GetCurrentProcess();
		FILETIME creationTime; // time that process was created
		FILETIME exitTime; // undefined if process has not exited
		FILETIME kernelTime; // ru_stime
		FILETIME userTime; // ru_utime
		if (GetProcessTimes(currentProcess, &creationTime, &exitTime, &kernelTime, &userTime) == 0) {
			return false; // GetLastError();
		}
		ulong toMicroseconds(FILETIME ft)  {
			return (ft.dwLowDateTime | cast(ulong) ft.dwHighDateTime << 32) / 10;
		}
		r.kernelTimeUs = toMicroseconds(kernelTime);
		r.userTimeUs = toMicroseconds(userTime);
	} else version(Posix) {
		rusage rusageStruct;
		if (getrusage(RUSAGE_SELF, &rusageStruct) == -1) {
			return false; //errno
		}
		auto toMicroseconds(timeval t) {
			return cast(ulong) t.tv_sec * 1_000_000 + t.tv_usec;
		}
		r.kernelTimeUs = toMicroseconds(rusageStruct.ru_stime);
		r.userTimeUs = toMicroseconds(rusageStruct.ru_utime);
	}
	return true;
}

On Windows you need to link to "Psapi.lib", e.g. with pragma(lib, "Psapi.lib") or libs "Psapi.lib" in dub.sdl.

On Friday, 7 May 2021 at 08:52:13 UTC, Dennis wrote:

For completeness, the imports it uses:

version(Windows) {
	import core.sys.windows.windows;
	import core.sys.windows.psapi: PROCESS_MEMORY_COUNTERS, GetProcessMemoryInfo;
} else version(Posix) {
	import core.sys.posix.sys.resource: rusage, getrusage, RUSAGE_SELF, timeval;
} else {
	static assert(0, "unsupported platform");
}

On Friday, 7 May 2021 at 08:58:33 UTC, Dennis wrote:

version(Windows) {
	import core.sys.windows.windows;
	import core.sys.windows.psapi: PROCESS_MEMORY_COUNTERS, GetProcessMemoryInfo;
} else version(Posix) {
	import core.sys.posix.sys.resource: rusage, getrusage, RUSAGE_SELF, timeval;
} else {
	static assert(0, "unsupported platform");
}

Thanks a lot.

Kind regards
André