So, here is the full code:

enum Color {none=0,red=1,black=2};
enum sColor {black=0,white=1};
class Square {
public:
    this(Color color, sColor Scolor) {
    this.color = color;
    this.Scolor = Scolor;
    }
    Color color;
    sColor Scolor;
}
import std.stdio;
void cPrintboard(Square[8][8] square)
{
    for(int i=0;i<8;i++)
    {
        for(int j=0;j<8;j++)
        {
            final switch(square[i][j].color) {
            case Color.none:
                write(" n ");
                break;
            case Color.red:
                write(" r ");
                break;
            case Color.black:
                write(" b ");
                break;
            }
        }
        writeln("");
    }
    writeln("");
}
void sPrintboard(Square[8][8] square) {
    for(int i=0;i<8;i++)
    {
        for(int j=0;j<8;j++)
        {
            final switch(square[i][j].Scolor) {
            case sColor.white:
                write(" w ");
                break;
            case sColor.black:
                write(" b ");
                break;
            }
        }
        writeln("");
    }
    writeln("");
}
bool isEven(int a)
{
    return a&1;
}
void main()
{
    Square[8][8] square;
    for(int i=7;7>=0;i--)
    {
        for(int j=7;j>=0;j--)
        {
            if((isEven(i)&&isEven(j))^(!isEven(i)&&!isEven(j)))
                square[i][j] = new Square(Color.none, sColor.white);
            else if((!isEven(i)&&isEven(j))^(isEven(i)&&!isEven(j)))
                square[i][j] = new Square(Color.none,sColor.black);
            else
                assert(false);

        }
    }
    for(int i=2;i>=0;i--)
    {
        for(int j=7;i>=0;j--)
        {
            if((!isEven(i)&&isEven(j))^(isEven(i)&&!isEven(j)))
                square[i][j].color = Color.red; //The program breaks here, with a range violation message
            else
            {

            }
        }
    }
    cPrintboard(square);
    sPrintboard(square);
}

What am I doing wrong here? Is it the 'for' loop?

On Sunday, 11 April 2021 at 19:45:30 UTC, Ruby The Roobster wrote:

square[i][j] = new Square(Color.none, sColor.white);

On Sunday, 11 April 2021 at 19:45:30 UTC, Ruby The Roobster wrote:

Yes, there is a 7 where there should be an i on this line:

   for(int i=7;7>=0;i--)

This will go on forever, so you get a range error as soon as i < 0.

—Bastiaan.

On Sunday, 11 April 2021 at 20:41:35 UTC, Bastiaan Veelo wrote:

   for(int i=7;7>=0;i--)

I have fixed this.

On Sunday, 11 April 2021 at 20:41:35 UTC, Bastiaan Veelo wrote:
[...]

   for(int i=7;7>=0;i--)

Can't these kinds of errors be eliminated by using foreach loops?:

    Square[8][8] square;
    foreach (int i, ref v; square)
    {
        foreach(int j, ref w; v)
        {
            if((isEven(i)&&isEven(j))^(!isEven(i)&&!isEven(j)))
                w = new Square(Color.none, sColor.white);
            else if((!isEven(i)&&isEven(j))^(isEven(i)&&!isEven(j)))
                w = new Square(Color.none,sColor.black);
            else
                assert(false);

        }
    }

On Monday, 12 April 2021 at 18:01:02 UTC, kdevel wrote:

   for(int i=7;7>=0;i--)

    Square[8][8] square;
    foreach (int i, ref v; square)
    {
        foreach(int j, ref w; v)
        {
            if((isEven(i)&&isEven(j))^(!isEven(i)&&!isEven(j)))
                w = new Square(Color.none, sColor.white);
            else if((!isEven(i)&&isEven(j))^(isEven(i)&&!isEven(j)))
                w = new Square(Color.none,sColor.black);
            else
                assert(false);

        }
    }

Yup

On Monday, 12 April 2021 at 18:13:38 UTC, Imperatorn wrote:
[...]

D can be so much fun!

import std.stdio;

enum Color {none = " n ", red = " r ", black = " b "};
enum sColor {black= " b ", white= " w "};
class Square {
public:
    this(Color color, sColor Scolor) {
        this.color = color;
        this.Scolor = Scolor;
    }
    Color color;
    sColor Scolor;
}

void Printboard (alias Q) (Square[8][8] square) {
    foreach (int i, ref v; square)
    {
        foreach(int j, ref w; v)
        {
           string s = Q (w);
           write (s);
        }
        writeln;
    }
    writeln;
}

bool isEven(int a)
{
    return a&1;
}

void main()
{
    Square[8][8] square;
    foreach (int i, ref v; square)
        foreach(int j, ref w; v)
        {
            auto color = (i + j).isEven
               ? sColor.black
               : sColor.white;
            w = new Square(Color.none, color);
        }
    foreach (int i, ref v; square)
    {
        if (i > 2)
            continue;
        foreach (int j, ref w; v)
            w.color = (i + j).isEven
               ? Color.red
               : w.color;
    }
    Printboard!(w => w.color) (square);
    Printboard!(w => w.Scolor) (square);
}

On Monday, 12 April 2021 at 19:19:12 UTC, kdevel wrote:

import std.stdio;

[...]

Of course :D