Why does disabling a struct's postblit increase its sizeof by one word?

The following holds:

struct S { @disable this(this); int _; }
struct T { int _; }
static assert(S.sizeof == 16);
static assert(T.sizeof == int.sizeof);

. Why is this needed?

On Saturday, 2 March 2024 at 15:25:48 UTC, Per Nordlöw wrote:

struct S { @disable this(this); int _; }
struct T { int _; }
static assert(S.sizeof == 16);
static assert(T.sizeof == int.sizeof);

Not according to run.dlang.io, for all available DMD versions. Perhaps your tested S was nested in some function/aggregate and so had an implicit context pointer.

On Saturday, 2 March 2024 at 19:11:42 UTC, kinke wrote:

Ahh. Yes. Indeed. My mistake. Thanks.

On Saturday, 2 March 2024 at 19:28:08 UTC, Per Nordlöw wrote:

Thanks. Neither my websearches nor ChatGPT plus couldn't figure that out.

On Saturday, 2 March 2024 at 19:29:47 UTC, Per Nordlöw wrote:

FYI, you can dump the layout of a struct, including hidden fields, by iterating over its .tupleof property:

void main()
{
    struct S
    {
        @disable this(this);
        int n;
    }

    static foreach (field; S.tupleof)
        pragma(msg,
            typeof(field).stringof, " ",
            __traits(identifier, field), " ",
            "at ", field.offsetof
        );
}

This example prints out

int n at 0LU
void* this at 8LU