Merhaba,

Bu sabah, şu başlıkta yetenekli chunks() ile tanıştım. Eğer kendisine dizi verirseniz, parçalı aralığa veya isteğe bağlı ve kolayca diziye çevirebilirsiniz. Üstelik sadece dizi değil aralık da alıyor!

Peki ne yapıyor?

İlk parametre olarak ister aralık (rangeNum) verin isterseniz dizi (arrayNum), verdiğiniz ikinci parametreye göre (bu değer, parça adeti değil her parçanın max. uzunluğu) bölüyor:

import std;

void main() {
  auto arrayNum = 1.iota(10).array;

  typeid(arrayNum).writeln(": ", arrayNum);
//int[]: [1, 2, 3, 4, 5, 6, 7, 8, 9]

  auto phoneKeys = arrayNum.chunks(3).array;
  phoneKeys.writefln!"%(%s\n%)";
  "[*, 0, #]".writeln; // EVET, KOLAYA KAÇTIM :)

// #2
  auto rangeNum = 1.iota(10);

  typeid(rangeNum).writeln(": ", rangeNum);
//std.range.iota!(int, int).iota.Result: [1, 2, 3, 4, 5, 6, 7, 8, 9]

  phoneKeys = rangeNum.chunks(3).map!array.array;
  phoneKeys.writefln!"%(%s\n%)";
  "[*, 0, #]".writeln; // EVET, KOLAYA KAÇTIM :)
}/* ÇIKTISI:
[1, 2, 3]
[4, 5, 6]
[7, 8, 9]
[*, 0, #]
*/

Farketmişsinizdir, örneğin 2. bölümünde aralık verdiğimiz için devamını map'lemeden diziye çeviremiyoruz! Ama bu sefer veriyi işlemek adına daha çok olanağa sahip olabiliriz.

Kolay gelsin...

Yukarısı hakikaten GBS idi, ya buna ne demeli:

import std;

void main() {
  auto iller = ["Adana","Adıyaman","Afyon", "Ağrı",
                "Amasya","Ankara","Antalya","Artvin",
                "Aydın","Balıkesir","Bilecik","Bingöl",
                "Bitlis","Bolu","Burdur","Bursa"];

  // 2. karakteri benziyorsa gruplandırır:
  foreach(grup; iller.chunkBy!
         ((a,b) => a[1] == b[1])
  ) if(grup.array.length > 1) {
    grup.writeln;
  }

  // Son karakteri benziyorsa gruplandırır:
  foreach(grup; iller.chunkBy!
         ((a,b) => a[$-1] == b[$-1])
  ) if(grup.array.length > 1) {
    grup.writeln;
  }
}

Bir de chunkBy varmış! Mutlaka deneyin çok güzel bir örnek!

Başarılar...

On Saturday, 15 January 2022 at 23:36:22 UTC, Ali Çehreli wrote:

Haklısınız hocam :)

Şimdi yeni öğrediklerim sayesinde if de uçtu:

foreach(grup; iller.chunkBy!
         ((a,b) => a[1] == b[1]).
         filter!(r => r.count > 1))
{
  grup.writeln;
}

On Sunday, 16 January 2022 at 07:50:31 UTC, Salih Dincer wrote:

foreach(grup; iller.chunkBy!
         ((a,b) => a[1] == b[1]).
         filter!(r => r.count > 1))
{
  grup.writeln;
}

foreach de kaldırılabilir. Ama bence kod okunabilirliğini azaltıyor.

iller.chunkBy!((a,b) => a[1] == b[1]).filter!(r => r.count > 1).each!(arr => arr.writeln);

On Monday, 17 January 2022 at 08:14:17 UTC, Ferhat Kurtulmuş wrote:

Kesinlikle! Ama UFCS'de insanın hoşuna giden bir taraf var. Sanırım her şeyde olduğu gibi ölçüsüz davranmamak gerekiyor. Hani insanoğlunun bir huyu vardır ya aşırıya kaçma yönünde! Belki o zaman (programlama araçlarınını dengeli kullanarak), daha okunaklı ve her manasıyla verimli kodlar yazılabilir.

İnanmayacaksınız! Tam bilgisayarı açmış ve Community/Forum bağlantısına tıklıyorken yanlışlıkla sürükle bırak yapıp ana sayfaya geçtim. Pufff nidalarıyla aynı işlemi tekrar edecektim ki "dur bir dakika" dedim kendi kendime! Ana sayfada konuyla alakalı şu örneği gördüm:

    import std.algorithm, std.stdio
    import std.file, std.range;

    enum cols = 14;

void main()
{
    // Split file into 14-byte chunks per row
    thisExePath.File("rb").byChunk(cols).take(20).each!(chunk =>
        // Use range formatting to format the
        // hexadecimal part and align the text part
        writefln!"%(%02X %)%*s  %s"(
            chunk,
            3 * (cols - chunk.length), "", // Padding
            chunk.map!(c => // Replace non-printable
                c < 0x20 || c > 0x7E ? '.' : char(c))));
}

Aslında tek satırlık (ikiye bölersek, veriyi okuyup parçalama ve biçimli şekilde ekrana yazma) kodu görmekteyiz! Ama bu örnek, başka bir dilde biraz uğraştırırdı. Ne bileyim, birden fazla işlev ve birçok değişken ile başa çıkılması vakit alıcı olurdu...

Özetle, başında beri teorik yaklaştığımız chunks() olanağı bize pratikte böyle sonuçlar verebiliyor.

Sevgiler, saygılar...